Heading

El formato condicional es una forma fantástica de visualizar rápidamente los datos en una hoja de cálculo. Con el formato condicional, puede hacer cosas como resaltar las fechas de los próximos 30 días, marcar los problemas de entrada de datos, resaltar las filas que contienen los mejores clientes, mostrar los duplicados y mucho más.

Excel viene con un gran número de «preajustes» que facilitan la creación de nuevas reglas sin fórmulas. Sin embargo, también puede crear reglas con sus propias fórmulas personalizadas. Al utilizar su propia fórmula, usted se hace cargo de la condición que desencadena una regla, y puede aplicar exactamente la lógica que necesita. Las fórmulas le dan el máximo poder y flexibilidad.

Por ejemplo, utilizando el preajuste «Igual a», es fácil resaltar las celdas iguales a «manzana».

¿Pero qué pasa si quiere resaltar las celdas iguales a «manzana» o «kiwi» o «lima»? Claro, puede crear una regla para cada valor, pero eso es un montón de problemas. En su lugar, puedes utilizar simplemente una regla basada en una fórmula con la función OR:

Aquí tienes el resultado de la regla aplicada al rango B4:F8 de esta hoja de cálculo:

Aquí tienes la fórmula exacta utilizada:

=OR(B4="apple",B4="kiwi",B4="lime")

Inicio rápido
Puedes crear una regla de formato condicional basada en una fórmula en cuatro sencillos pasos:
1. Seleccione las celdas a las que desea dar formato.

2. Cree una regla de formato condicional y seleccione la opción Fórmula

3. Introduzca una fórmula que devuelva TRUE o FALSE.

4. Establezca las opciones de formato y guarde la regla.

La función ISODD sólo devuelve TRUE para números impares, activando la regla:

Vídeo: Cómo aplicar el formato condicional con una fórmula
También ofrecemos formación en vídeo sobre este tema.
Lógica de las fórmulas
Las fórmulas que aplican el formato condicional deben devolver TRUE o FALSE, o equivalentes numéricos. He aquí algunos ejemplos:
=ISODD(A1)=ISNUMBER(A1)=A1>100=AND(A1>100,B1<50)=OR(F1="MN",F1="WI")

Todas las fórmulas anteriores devuelven TRUE o FALSE, por lo que funcionan perfectamente como activadores del formato condicional.
Cuando se aplica el formato condicional a un rango de celdas, se introducen las referencias de celdas con respecto a la primera fila y columna de la selección (es decir, la celda superior izquierda). El truco para entender cómo funcionan las fórmulas de formato condicional es visualizar la misma fórmula aplicada a cada celda de la selección, con las referencias de celda actualizadas como es habitual. Imagina que introduces la fórmula en la celda superior izquierda de la selección, y luego copias la fórmula en toda la selección. Si tiene problemas con esto, consulte la sección sobre fórmulas ficticias más adelante.

Ejemplos de fórmulas
A continuación se muestran ejemplos de fórmulas personalizadas que puede utilizar para aplicar el formato condicional. Algunos de estos ejemplos pueden crearse utilizando los preajustes incorporados de Excel para resaltar celdas, pero las fórmulas personalizadas pueden ir mucho más allá de los preajustes, como puedes ver a continuación.
También puedes ver: Más de 30 fórmulas de formato condicional 
Resaltar pedidos de Texas
Para resaltar las filas que representan pedidos de Texas (abreviado TX), utilice una fórmula que bloquee la referencia a la columna F:
=$F5="TX"


Para más detalles, consulta este artículo: Resaltar filas con formato condicional.
Vídeo: Cómo resaltar filas con formato condicional
Resaltar fechas en los próximos 30 días
Para resaltar las fechas que ocurren en los próximos 30 días, necesitamos una fórmula que (1) se asegure de que las fechas están en el futuro y (2) se asegure de que las fechas son de 30 días o menos desde hoy. Una forma de hacerlo es utilizar la función AND junto con la función NOW de la siguiente manera:
=AND(B4>NOW(),B4<=(NOW()+30))

Con una fecha actual del 18 de agosto de 2016, el formato condicional resalta las fechas de la siguiente manera:

La función AHORA devuelve la fecha y la hora actuales. Para más detalles sobre cómo funciona esta fórmula, consulte este artículo: Resaltar fechas en los próximos N días.
Resaltar diferencias de columnas
Dado dos columnas que contienen información similar, puede utilizar el formato condicional para detectar diferencias sutiles. La fórmula utilizada para desencadenar el formato de abajo es:

=$B4<>$C4

Vea también: una versión de esta fórmula que utiliza la función EXACT para hacer una comparación sensible a mayúsculas y minúsculas.
Resaltar los valores que faltan
Para resaltar los valores de una lista que faltan en otra, puede utilizar una fórmula basada en la función COUNTIF:
=COUNTIF(list,B5)=0


Esta fórmula simplemente comprueba cada valor de la Lista A con los valores del rango nombrado "lista" (D5:D10). Cuando el recuento es cero, la fórmula devuelve TRUE y activa la regla, que resalta los valores de la Lista A que faltan en la Lista B.
Vídeo: Cómo encontrar los valores que faltan con COUNTIF
Resaltar las propiedades con más de 3 dormitorios por debajo de 350 mil dólares
Para encontrar las propiedades en esta lista que tienen al menos 3 dormitorios pero son menos de 300 mil dólares, puede utilizar una fórmula basada en la función AND:
=AND($C5<350000,$D5>=3)

Los signos de dólar ($) bloquean la referencia a las columnas C y D, y la función AND se utiliza para asegurarse de que ambas condiciones son TRUE. En las filas en las que la función AND devuelve TRUE, se aplica el formato condicional:


Resaltar los valores superiores (ejemplo dinámico)
Aunque Excel tiene ajustes preestablecidos para los "valores superiores", este ejemplo muestra cómo hacer lo mismo con una fórmula, y cómo las fórmulas pueden ser más flexibles. Al utilizar una fórmula, podemos hacer que la hoja de trabajo sea interactiva: cuando se actualiza el valor en F2, la regla responde instantáneamente y resalta los nuevos valores.

La fórmula utilizada para esta regla es:
=B4>=LARGE(data,input)

Donde "datos" es el rango nombrado B4:G11, y "entrada" es el rango nombrado F2. Esta página tiene detalles y una explicación completa.
Gráficos de Gantt
Aunque no lo creas, puedes incluso utilizar fórmulas para crear sencillos gráficos de Gantt con formato condicional como este:

Esta hoja de trabajo utiliza dos reglas, una para las barras, y otra para el sombreado del fin de semana:
=AND(D$4>=$B5,D$4<=$C5) // bars=WEEKDAY(D$4,2)>5 // weekends

Este artículo explica la fórmula para las barras, y este artículo explica la fórmula para el sombreado del fin de semana.
Cuadro de búsqueda simple
Un truco genial que puedes hacer con el formato condicional es construir un cuadro de búsqueda simple. En este ejemplo, una regla resalta las celdas de la columna B que contienen el texto escrito en la celda F2:

La fórmula utilizada es:
=ISNUMBER(SEARCH($F$2,B2))

Para más detalles y una explicación completa, ver:

Artículo: Cómo resaltar celdas que contienen un texto específico 
Artículo: Cómo resaltar filas que contienen un texto específico 
Vídeo: Cómo construir un cuadro de búsqueda para resaltar datos 

Solución de problemas
Si no puedes conseguir que tus reglas de formato condicional se disparen correctamente, lo más probable es que haya un problema con tu fórmula. En primer lugar, asegúrate de que has comenzado la fórmula con un signo de igualdad (=). Si te olvidas de este paso, Excel convertirá silenciosamente toda tu fórmula en texto, haciéndola inútil. Para solucionarlo, simplemente elimine las comillas dobles que Excel ha añadido a ambos lados y asegúrese de que la fórmula comienza con iguales (=).
Si su fórmula se ha introducido correctamente, pero no está activando la regla, puede que tenga que indagar un poco más. Normalmente, puede utilizar la tecla F9 para comprobar los resultados de una fórmula, o utilizar la función Evaluar para recorrer una fórmula. Lamentablemente, no puedes utilizar estas herramientas con las fórmulas de formato condicional, pero puedes utilizar una técnica llamada "fórmulas ficticias".
Fórmulas ficticias
Las fórmulas ficticias son una forma de probar tus fórmulas de formato condicional directamente en la hoja de cálculo, para que puedas ver lo que realmente están haciendo. Esto puede suponer un gran ahorro de tiempo cuando te cuesta conseguir que las referencias a las celdas funcionen correctamente.
En pocas palabras, introduces la misma fórmula en un rango de celdas que coincide con la forma de tus datos. Esto te permite ver los valores devueltos por cada fórmula, y es una gran manera de visualizar y entender cómo funciona el formato condicional basado en fórmulas. Para una explicación detallada, consulte este artículo.

Vídeo: Probar el formato condicional con fórmulas ficticias
Limitaciones
Hay algunas limitaciones que vienen con el formato condicional basado en fórmulas:

No puede aplicar iconos, escalas de color o barras de datos con una fórmula personalizada. Está limitado al formato de celda estándar, incluidos los formatos numéricos, la fuente, el color de relleno y las opciones de borde.
No puede utilizar ciertas construcciones de fórmulas como uniones, intersecciones o constantes de matrices para los criterios de formato condicional.
No puede hacer referencia a otros libros de trabajo en una fórmula de formato condicional.
A veces puede trabajar alrededor de #2 y #3. Usted puede ser capaz de mover la lógica de la fórmula en una celda en la hoja de trabajo, a continuación, hacer referencia a esa celda en la fórmula en su lugar. Si usted está tratando de utilizar una constante de matriz, trate de crear un rango con nombre en su lugar.